AS3 経過時間を表示する（テキスト版）

package {
	
	import flash.display.*;
	import flash.events.*;
	import flash.text.*;
	import flash.utils.getTimer;
	
	public class Sample20091208 extends Sprite {
		
		private var _startBtn:TextBtn;
		private var _timeText:TextField;
		private var _hackTime:Number;
		
		public function Sample20091208():void {
			
			_init();
			
		}
		
		private function _init():void {
			
			_timeText= new TextField();
			_timeText.width = 200;
			_timeText.y = 2;
			_timeText.autoSize = TextFieldAutoSize.CENTER;
			_timeText.selectable=false;
			addChild(_timeText);
			
			_timeText.x = stage.stageWidth / 2 - _timeText.width / 2;
			_timeText.y = stage.stageHeight / 2 - _timeText.height / 2;
			
			_startBtn = new TextBtn("スタート");
			addChild(_startBtn);
			_startBtn.x = stage.stageWidth / 2 - _startBtn.width / 2;
			_startBtn.y = stage.stageHeight -40;
			
			_convertTime(0);
			
			_startBtn.addEventListener(MouseEvent.MOUSE_DOWN, _startHandler);

		}
		
		private function _startHandler(e:MouseEvent):void {
			
			_hackTime = getTimer();
		
			addEventListener(Event.ENTER_FRAME, _onEnterFrameHandler);
			
		}
		
		private function _onEnterFrameHandler(e:Event):void {
			
			/*
			 * ムービーが動作している時間をミリ秒で返してくれる _hackTimeでどれ位時間が経過したかを取得して現在の時間から引く
			 */
		
			var progressTime:uint = getTimer() - _hackTime;
			
			_convertTime(progressTime);
		}
		
		private function _convertTime(_time:Number):void {
			
			/* ミリ秒を取得 */
			var _mil:Number= _time;
			/* 秒を取得 */
			var _sec:Number = Math.floor(_mil / 1000);
			/* 分を取得 */
			var _min:Number = Math.floor(_sec / 60);
			/*　時を取得 */
			var _hou:Number = Math.floor(_min / 60);
			
			/* 秒・分なら60　ミリ秒なら1000を超えないように処理を施す。この作業を省くと65秒などがありえてしまいます。 */
			
			_mil %= 1000;
			_sec %= 60;
			_min %= 60;
			
			/* 三桁は必要ないので10で割る */
			
			_mil = uint(_mil / 10);
			
			/* 表示に関する制御(二桁以下なら0を表記する) */
			
			var _milStr:String = String(_mil);
			_milStr = ((_milStr.length < 2) ? "0"  : "") + _milStr;

			var _secStr:String = String(_sec);
			_secStr = ((_secStr.length < 2) ? "0"  : "") + _secStr;
			
			var _minStr:String = String(_min);
			_minStr = ((_minStr.length < 2) ? "0"  : "") + _minStr;
			
			var _houStr:String = String(_hou);
			_houStr = ((_houStr.length < 2) ? "0"  : "") + _houStr;
			
			_timeText.text = _houStr + ":" + _minStr + ":" + _secStr + ":" + _milStr;
			
		}
	}
}

import flash.display.Sprite; 
import flash.text.*;
 
dynamic class TextBtn extends Sprite {
	
	public function TextBtn(str:String):void {
		
		this.graphics.beginFill(0x666666);
		this.graphics.drawRect(0,0, 100, 22);
		this.graphics.endFill();

		this.buttonMode = true;
		this.mouseChildren = false;
		
		var tf= new TextField();
		tf.width = 100;
		tf.y = 2;
		tf.autoSize = TextFieldAutoSize.CENTER;	//autoSizeを指定しないと高さが100pxになる
		tf.selectable=false;
		this.addChild(tf);
			
		var format:TextFormat=new TextFormat();
		format.color=0xFFFFFF;
		format.size = 12;
		tf.defaultTextFormat = format;
		tf.text = str;
		
	}
}